source: trunk/UCore.pas

unit UCore;

interface

uses
  Classes, SysUtils, FileUtil, Controls, ActnList, UDatabase, UTranslator,
  UApplicationInfo, UPersistentForm, Forms, URegistry, UScaleDPI;

type
  { TCore }

  TCore = class(TDataModule)
    AAbout: TAction;
    ADatabaseConnect: TAction;
    ADatabaseDisconnect: TAction;
    ApplicationInfo1: TApplicationInfo;
    APreferences: TAction;
    AExit: TAction;
    ActionList1: TActionList;
    Translator1: TTranslator;
    ImageList1: TImageList;
    PersistentForm1: TPersistentForm;
    ScaleDPI1: TScaleDPI;
    procedure AAboutExecute(Sender: TObject);
    procedure ADatabaseConnectExecute(Sender: TObject);
    procedure ADatabaseDisconnectExecute(Sender: TObject);
    procedure AExitExecute(Sender: TObject);
    procedure APreferencesExecute(Sender: TObject);
    procedure Translator1Translate(Sender: TObject);
    procedure DataModuleCreate(Sender: TObject);
    procedure DataModuleDestroy(Sender: TObject);
  private
    FDbClient: TDbClient;
    Initialized: Boolean;
    procedure SetDbClient(AValue: TDbClient);
  public
    Preferences: TPreferences;
    DbManager: TDbManager;
    procedure LoadConfig;
    procedure SaveConfig;
    procedure Init;
    procedure Done;
    procedure UpdateInterface;
    property DbClient: TDbClient read FDbClient write SetDbClient;
  end;

var
  Core: TCore;

const
  DefaultRegKey = '\Software\Chronosoft\MyData';


implementation

uses
  UFormTables, UFormConnect, UAboutDialog, UFormDatabases, UFormPreferences,
  UFormMain;

{$R *.lfm}

{ TCore }

procedure TCore.DataModuleCreate(Sender: TObject);
begin
  DbManager := TDbManager.Create;
  Preferences := TPreferences.Create;
end;

procedure TCore.DataModuleDestroy(Sender: TObject);
begin
  DbClient := nil;
  FreeAndNil(Preferences);
  FreeAndNil(DbManager);
end;

procedure TCore.AExitExecute(Sender: TObject);
begin
  FormMain.Close;
end;

procedure TCore.ADatabaseDisconnectExecute(Sender: TObject);
begin
  DbClient := nil;
end;

procedure TCore.ADatabaseConnectExecute(Sender: TObject);
begin
  with TFormDatabases.Create(nil) do
  try
    if ShowModal = mrOk then begin
      DbClient := nil;
      DbClient := SelectedProfile.GetClient;
    end;
  finally
    Free;
  end;
end;

procedure TCore.AAboutExecute(Sender: TObject);
begin
  with TAboutDialog.Create(nil) do
  try
    ApplicationInfo := ApplicationInfo1;
    Show;
  finally
    Free;
  end;
end;

procedure TCore.APreferencesExecute(Sender: TObject);
begin
  with TFormPreferences.Create(nil) do
  try
    Load(Preferences);
    if ShowModal = mrOk then Save(Preferences);
  finally
    Free;
  end;
end;

procedure TCore.Translator1Translate(Sender: TObject);
var
  I: Integer;
begin
  for I := 0 to DbManager.DataTypes.Count - 1 do begin
    TDataType(DbManager.DataTypes[I]).Title := Translator1.TranslateText(TDataType(DbManager.DataTypes[I]).Title, TDataType(DbManager.DataTypes[I]).Title);
  end;
end;

procedure TCore.SetDbClient(AValue: TDbClient);
begin
  if FDbClient = AValue then Exit;
  if Assigned(FDbClient) then begin
    FormMain.FormTables.DbClient := nil;
    DbClient.Save;
    FreeAndNil(FDbClient);
  end;
  FDbClient := AValue;
  if Assigned(FDbClient) then begin
    DbClient.Load;
    Preferences.LastDatabaseName := FDbClient.ConnectProfile.Name;
    FormMain.FormTables.DbClient := DbClient;
  end;
  UpdateInterface;
end;

procedure TCore.LoadConfig;
begin
  with TRegistryEx.Create do
  try
    CurrentContext := TRegistryContext.Create(rrKeyCurrentUser, DefaultRegKey);
    Preferences.RememberDatabase := GetValue('RememberDatabase', True);
    Preferences.LastDatabaseName := GetValue('LastDatabaseName', '');
    Translator1.Language := Translator1.Languages.SearchByCode(
      GetValue('Language', ''));
  finally
    Free;
  end;
  DbManager.ConnectProfiles.LoadFromRegistry(TRegistryContext.Create(rrKeyCurrentUser, DefaultRegKey + '\Database'));
end;

procedure TCore.SaveConfig;
begin
  with TRegistryEx.Create do
  try
    CurrentContext := TRegistryContext.Create(rrKeyCurrentUser, DefaultRegKey);
    SetValue('RememberDatabase', Preferences.RememberDatabase);
    SetValue('LastDatabaseName', Preferences.LastDatabaseName);
    SetValue('Language', Translator1.Language.Code);
  finally
    Free;
  end;
  DbManager.ConnectProfiles.SaveToRegistry(TRegistryContext.Create(rrKeyCurrentUser, DefaultRegKey + '\Database'));
end;

procedure TCore.Init;
var
  ConnectProfile: TDbConnectProfile;
begin
  if not Initialized then begin
    {$IFDEF UNIX}
    // If installed in Linux system then use installation directory for po files
    if Application.ExeName = '/usr/bin/MyData' then
      Translator1.POFilesFolder := '/usr/share/MyData/languages';
    {$ENDIF}
    Initialized := True;
    LoadConfig;
    UpdateInterface;
    if Preferences.RememberDatabase then begin
      ConnectProfile := DbManager.ConnectProfiles.SearchByName(Preferences.LastDatabaseName);
      if Assigned(ConnectProfile) then begin
        DbClient := ConnectProfile.GetClient;
      end;
    end else ADatabaseConnect.Execute;
  end;
end;

procedure TCore.Done;
begin
  SaveConfig;
  DbClient := nil;
end;

procedure TCore.UpdateInterface;
begin
  ADatabaseDisconnect.Enabled := Assigned(DbClient);
  FormMain.UpdateInterface;
end;

end.