source: trunk/UCore.pas

unit UCore;

{$mode Delphi}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, ActnList, UProject, UCoolTranslator, UFGraphics,
  UPersistentForm, Controls, Graphics, ExtDlgs, ExtCtrls, URegistry,
  UApplicationInfo, Registry;

const
  ZoomFactor = 1.5;

type
  { TCore }

  TCore = class(TDataModule)
    ASettings: TAction;
    AToolMove: TAction;
    AToolPen: TAction;
    AImageNegative: TAction;
    AImageGradient: TAction;
    AImageMirror: TAction;
    AImageFlip: TAction;
    AImageRandom: TAction;
    AFileSaveAs: TAction;
    AFileSave: TAction;
    AFileClose: TAction;
    AFileOpen: TAction;
    ApplicationInfo1: TApplicationInfo;
    AZoomNormal: TAction;
    AZoomAll: TAction;
    AZoomIn: TAction;
    AZoomOut: TAction;
    AImageClear: TAction;
    AExit: TAction;
    AFileNew: TAction;
    ActionList1: TActionList;
    CoolTranslator1: TCoolTranslator;
    ImageList1: TImageList;
    OpenPictureDialog1: TOpenPictureDialog;
    PersistentForm1: TPersistentForm;
    SavePictureDialog1: TSavePictureDialog;
    procedure AExitExecute(Sender: TObject);
    procedure AFileNewExecute(Sender: TObject);
    procedure AFileCloseExecute(Sender: TObject);
    procedure AFileOpenExecute(Sender: TObject);
    procedure AFileSaveAsExecute(Sender: TObject);
    procedure AFileSaveExecute(Sender: TObject);
    procedure AImageClearExecute(Sender: TObject);
    procedure AImageFlipExecute(Sender: TObject);
    procedure AImageGradientExecute(Sender: TObject);
    procedure AImageMirrorExecute(Sender: TObject);
    procedure AImageNegativeExecute(Sender: TObject);
    procedure AImageRandomExecute(Sender: TObject);
    procedure ASettingsExecute(Sender: TObject);
    procedure AToolMoveExecute(Sender: TObject);
    procedure AToolPenExecute(Sender: TObject);
    procedure AZoomAllExecute(Sender: TObject);
    procedure AZoomInExecute(Sender: TObject);
    procedure AZoomNormalExecute(Sender: TObject);
    procedure AZoomOutExecute(Sender: TObject);
    procedure DataModuleCreate(Sender: TObject);
    procedure DataModuleDestroy(Sender: TObject);
  private
  public
    LastColorFormat: string;
    LastImageSize: TPoint;
    Project: TProject;
    RegistryContext: TRegistryContext;
    procedure ProjectOpen(FileName: string);
    procedure ProjectNew;
    procedure Init;
    procedure LoadConfig;
    procedure SaveConfig;
  end;

var
  Core: TCore;

implementation

{$R *.lfm}

uses
  UFormNew, UFormMain, Forms, UFormSettings;

{ TCore }

procedure TCore.DataModuleCreate(Sender: TObject);
begin
  RegistryContext := TRegistryContext.Create(ApplicationInfo1.RegistryRoot,
    ApplicationInfo1.RegistryKey);
  Project := TProject.Create;
end;

procedure TCore.DataModuleDestroy(Sender: TObject);
begin
  FreeAndNil(Project);
  SaveConfig;
end;

procedure TCore.ProjectOpen(FileName: string);
var
  Image: TImage;
begin
  FormMain.LastOpenedList1.AddItem(FileName);
  Image := TImage.Create(nil);
  Image.Picture.LoadFromFile(FileName);
  //Image.Picture.Bitmap.BeginUpdate(True);
  Project.Bitmap.Size := Point(Image.Picture.Bitmap.Width, Image.Picture.Bitmap.Height);
  //Project.Bitmap.LoadFromCanvas(Image.Picture.Bitmap.Canvas);
  Project.Bitmap.LoadFromBitmap(Image.Picture.Bitmap);
  //Image.Picture.Bitmap.EndUpdate;
  Image.Free;
  Project.View.ZoomAll(Project.Bitmap.Size);
  FormMain.Redraw;
  Project.FileName := FileName;
end;

procedure TCore.ProjectNew;
var
  ColorFormatIndex: Integer;
begin
  // Set default
  ColorFormatIndex := ColorFormatManager.FindByName(LastColorFormat);
  if ColorFormatIndex < ColorFormatManager.Formats.Count then
    Project.Bitmap.ColorFormat := ColorFormatManager.Formats[ColorFormatIndex]
    else Project.Bitmap.ColorFormat := ColorFormatManager.Formats[0];
  Project.Bitmap.Size := LastImageSize;

  Project.View.DestRect := Bounds(0, 0, FormMain.PaintBox1.Width, FormMain.PaintBox1.Height);
  Project.View.ZoomAll(Project.Bitmap.Size);
end;

procedure TCore.Init;
begin
  PersistentForm1.RegistryContext := RegistryContext;
  LoadConfig;

  ProjectNew;
  FormMain.Redraw;
end;

procedure TCore.LoadConfig;
begin
  with TRegistryEx.Create do
  try
    RootKey := RegistryContext.RootKey;
    OpenKey(RegistryContext.Key, True);

    LastColorFormat := ReadStringWithDefault('LastColorFormat', '');
    LastImageSize.X := ReadIntegerWithDefault('LastImageSizeX', 600);
    LastImageSize.Y := ReadIntegerWithDefault('LastImageSizeY', 400);
    if ValueExists('LanguageCode') then
      CoolTranslator1.Language := CoolTranslator1.Languages.SearchByCode(ReadStringWithDefault('LanguageCode', ''))
      else CoolTranslator1.Language := CoolTranslator1.Languages.SearchByCode('');
  finally
    Free;
  end;
end;

procedure TCore.SaveConfig;
begin
  with TRegistryEx.Create do
  try
    RootKey := RegistryContext.RootKey;
    OpenKey(RegistryContext.Key, True);

    WriteString('LastColorFormat', LastColorFormat);
    WriteInteger('LastImageSizeX', LastImageSize.X);
    WriteInteger('LastImageSizeY', LastImageSize.Y);
    if Assigned(CoolTranslator1.Language) and (CoolTranslator1.Language.Code <> '') then
      WriteString('LanguageCode', CoolTranslator1.Language.Code)
      else DeleteValue('LanguageCode');
  finally
    Free;
  end;
end;

procedure TCore.AFileNewExecute(Sender: TObject);
begin
  FormNew.DefaultSize := LastImageSize;
  if FormNew.ShowModal = mrOk then begin
    Project.Bitmap.ColorFormat := TColorFormat.Create;

    Project.FileName := 'New image';
    Project.Bitmap.Size := Point(FormNew.SpinEditWidth.Value, FormNew.SpinEditHeight.Value);
    Project.Bitmap.ColorFormat := ColorFormatManager.Formats[FormNew.ComboBoxColorFormat.ItemIndex];
//    Project.Bitmap.BackgroundColor.FromTColor(clBlack);
//    Project.Bitmap.DPI := FormNew.SpinEditDPI.Value;
    Project.View.ZoomAll(Project.Bitmap.Size);
    FormMain.Redraw;
    LastImageSize := Project.Bitmap.Size;
  end;
end;

procedure TCore.AZoomAllExecute(Sender: TObject);
begin
  with Core.Project do
    View.ZoomAll(Bitmap.Size);
  FormMain.Redraw;
end;

procedure TCore.AZoomInExecute(Sender: TObject);
begin
  Project.View.Zoom := Project.View.Zoom * ZoomFactor;
  FormMain.Redraw;
end;

procedure TCore.AZoomNormalExecute(Sender: TObject);
begin
  Project.View.Zoom := 1;
  FormMain.Redraw;
end;

procedure TCore.AZoomOutExecute(Sender: TObject);
begin
  Project.View.Zoom := Project.View.Zoom / ZoomFactor;
  FormMain.Redraw;
end;

procedure TCore.AExitExecute(Sender: TObject);
begin
  Application.Terminate;
end;

procedure TCore.AFileCloseExecute(Sender: TObject);
begin
  if not Project.Saved then AFileSave.Execute;
  Project.Free;
  FormMain.Redraw;
end;

procedure TCore.AFileOpenExecute(Sender: TObject);
begin
  if OpenPictureDialog1.Execute then begin
    ProjectOpen(OpenPictureDialog1.FileName);
  end;
end;

procedure TCore.AFileSaveAsExecute(Sender: TObject);
begin
  SavePictureDialog1.InitialDir := ExtractFileDir(Project.FileName);
  SavePictureDialog1.FileName := ExtractFileName(Project.FileName);
  if SavePictureDialog1.Execute then begin
    Project.FileName := SavePictureDialog1.FileName;
    FormMain.LastOpenedList1.AddItem(SavePictureDialog1.FileName);
    AFileSave.Execute;
  end;
end;

procedure TCore.AFileSaveExecute(Sender: TObject);
var
  Image: TImage;
begin
  if Project.FileName = '' then AFileSaveAs.Execute
  else begin
    FormMain.LastOpenedList1.AddItem(SavePictureDialog1.FileName);
    Image := TImage.Create(nil);
    Image.Picture.Bitmap.SetSize(Project.Bitmap.Size.X, Project.Bitmap.Size.Y);
    Project.Bitmap.PaintToBitmap(Image.Picture.Bitmap,
      Rect(0, 0, Image.Picture.Bitmap.Width, Image.Picture.Bitmap.Height));
    Image.Picture.SaveToFile(SavePictureDialog1.FileName);
    Image.Free;
    Project.Saved := True;
  end;
end;

procedure TCore.AImageClearExecute(Sender: TObject);
begin
  Project.Bitmap.Clear;
  (Project.Bitmap.Canvas.Pen.Color as TFColor).ColorFormat := Project.Bitmap.ColorFormat;
  (Project.Bitmap.Canvas.Pen.Color as TFColor).SetColorName(cnWhite);
  Project.Bitmap.Canvas.Pen.MoveTo(Point(80, 80));
  Project.Bitmap.Canvas.Pen.LineTo(Point(50, 20));
  FormMain.Redraw;
end;

procedure TCore.AImageFlipExecute(Sender: TObject);
begin
  Project.Bitmap.Flip;
  FormMain.Redraw;
end;

procedure TCore.AImageGradientExecute(Sender: TObject);
begin
  Core.Project.Bitmap.Gradient;
  FormMain.Redraw;
end;

procedure TCore.AImageMirrorExecute(Sender: TObject);
begin
  Project.Bitmap.Mirror;
  FormMain.Redraw;
end;

procedure TCore.AImageNegativeExecute(Sender: TObject);
begin
  Project.Bitmap.Negative;
  FormMain.Redraw;
end;

procedure TCore.AImageRandomExecute(Sender: TObject);
begin
  Project.Bitmap.Random;
  FormMain.Redraw;
end;

procedure TCore.ASettingsExecute(Sender: TObject);
begin
  FormSettings := TFormSettings.Create(nil);
  try
    FormSettings.Load;
    if FormSettings.ShowModal = mrOk then begin
      FormSettings.Save;
    end;
  finally
    FormSettings.Free;
  end;
end;

procedure TCore.AToolMoveExecute(Sender: TObject);
begin
  FormMain.ImageTool := itMoveView;
end;

procedure TCore.AToolPenExecute(Sender: TObject);
begin
  FormMain.ImageTool := itPen;
end;

end.