source: trunk/Target/TargetJava.pas

unit TargetJava;

interface

uses
  Classes, SysUtils, FileUtil, Target, BFTarget, Dialogs;

type

  { TTargetJava }

  TTargetJava = class(TBFTarget)
  private
    function GetMemoryCell: string;
  public
    constructor Create; override;
    procedure Compile; override;
    procedure Run; override;
  end;


implementation

{ TTargetJava }

constructor TTargetJava.Create;
begin
  inherited;
  FName := 'Java';
  FSourceExtension := '.java';
  FCompiledExtension := '.class';
  FRunExtension := '';
  FImageIndex := 24;
  FCapabilities := [tcCompile, tcRun];
  {$IFDEF WINDOWS}
  CompilerPath := 'c:\Program Files\Java\bin\javac.exe';
  ExecutorPath := 'c:\Program Files\Java\bin\java.exe';
  {$ENDIF}
  {$IFDEF UNIX}
  CompilerPath := '/usr/bin/javac';
  ExecutorPath := '/usr/bin/java';
  {$ENDIF}
end;

function TTargetJava.GetMemoryCell: string;
begin
  Result := 'Memory[Pos';
  if FProgram[FProgramIndex].RelIndex > 0 then
    Result := Result + ' + ' + IntToStr(FProgram[FProgramIndex].RelIndex)
  else if FProgram[FProgramIndex].RelIndex < 0 then
    Result := Result + ' - ' + IntToStr(Abs(FProgram[FProgramIndex].RelIndex));
  Result := Result + ']';
end;

procedure TTargetJava.Compile;
begin
  inherited;
  Indent := 0;
  FTargetCode := '';

  AddLine('import java.io.*;');
  AddLine;
  AddLine('public class ' + ProgramName + ' {');
  Inc(Indent);
  AddLine('public static void main(String args[]) throws IOException {');
  Inc(Indent);
  AddLine('char Memory[];');
  AddLine('int Pos;');
  AddLine('char ReadChar;');
  AddLine;
  AddLine('Memory = new char[' + IntToStr(MemorySize) + '];');
  AddLine('Pos = 0;');
  FProgramIndex := 0;
  while FProgramIndex < FProgram.Count do begin
    case FProgram[FProgramIndex].Command of
      cmPointerInc: AddLine('Pos = Pos + ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmPointerDec: AddLine('Pos = Pos - ' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmInc: AddLine(GetMemoryCell + ' = (char)((int)' + GetMemoryCell + ' + ' + IntToStr(FProgram[FProgramIndex].Parameter) + ');');
      cmDec: AddLine(GetMemoryCell + ' = (char)((int)' + GetMemoryCell + ' - ' + IntToStr(FProgram[FProgramIndex].Parameter) + ');');
      cmOutput: AddLine('System.out.print(' + GetMemoryCell + ');');
      cmInput: AddLine(GetMemoryCell + ' = (char)System.in.read();');
      cmSet: AddLine(GetMemoryCell + ' = (char)' + IntToStr(FProgram[FProgramIndex].Parameter) + ';');
      cmMultiply: AddLine(GetMemoryCell + ' = (char)((int)' + GetMemoryCell + ' + (int)Memory[Pos] * ' + IntToStr(FProgram[FProgramIndex].Parameter) + ');');
      cmLoopStart: begin
        AddLine('while(' + GetMemoryCell + ' != 0)');
        AddLine('{');
        Inc(Indent);
      end;
      cmLoopEnd: begin
        Dec(Indent);
        AddLine('}');
      end;
    end;
    Inc(FProgramIndex);
  end;
  Dec(Indent);
  AddLine('}');
  Dec(Indent);
  AddLine('}');

  CompileToFile;
end;

procedure TTargetJava.Run;
begin
  inherited;
  RunFromFile;
end;

end.