source: tags/1.1.0/UCore.pas

unit UCore;

{$mode delphi}

interface

uses
  Classes, SysUtils, FileUtil, UApplicationInfo, ULastOpenedList, UProject,
  UTranslator, UTarget, URegistry, Registry, Graphics, Controls, UScaleDPI,
  UPersistentForm, UTheme, UAboutDialog, UBFTarget;

type

  { TCore }

  TCore = class(TDataModule)
    AboutDialog: TAboutDialog;
    ApplicationInfo: TApplicationInfo;
    Translator: TTranslator;
    ImageListMain: TImageList;
    LastOpenedList: TLastOpenedList;
    PersistentForm1: TPersistentForm;
    ScaleDPI1: TScaleDPI;
    ThemeManager: TThemeManager;
    procedure DataModuleCreate(Sender: TObject);
    procedure DataModuleDestroy(Sender: TObject);
  private
    FCurrentTarget: TTarget;
    StoredDimension: TControlDimension;
    procedure SetCurrentTarget(AValue: TTarget);
    procedure ScaleDPI;
  public
    DataDir: string;
    Project: TProject;
    Targets: TTargetList;
    OpenProjectOnStart: Boolean;
    OptimizationLevel: TCompilerOptimization;
    CellSize: Integer;
    MemorySize: Integer;
    Optimizations: TOptimizations;
    procedure Init;
    procedure LoadFromRegistry(Context: TRegistryContext);
    procedure SaveToRegistry(Context: TRegistryContext);
    property CurrentTarget: TTarget read FCurrentTarget write SetCurrentTarget;
  end;

var
  Core: TCore;


implementation

{$R *.lfm}

uses
  UFormMain, Forms, LazFileUtils,
  // Targets
  UTargetInterpretter, UTargetFPC, UTargetJava, UTargetDelphi, UTargetJavascript,
  UTargetPHP, UTargetC, UTargetPython, UTargetCSharp;

const
  RecentFilesRegKey = 'RecentFiles';

{ TCore }

procedure TCore.DataModuleCreate(Sender: TObject);
const
  LinuxDataDir = '/usr/share/LazFuck';
  LinuxLanguagesDir = LinuxDataDir + '/Languages';
begin
  DataDir := '';
  {$IFDEF Linux}
  // If installed in Linux system then use installation shared game directory for data files
  if DirectoryExists(LinuxDataDir) then
    DataDir := LinuxDataDir;
  // If installed in Linux system then use installation directory for po files
  if not DirectoryExists(Translator.POFilesFolder) and DirectoryExists(LinuxLanguagesDir) then
    Translator.POFilesFolder := LinuxLanguagesDir;
  {$ENDIF}

  Project := TProject.Create;
  Targets := TTargetList.Create;
  StoredDimension := TControlDimension.Create;

  // Init targets list
  Targets.Add(TTargetInterpretter.Create);
  Targets.Add(TTargetDelphi.Create);
  Targets.Add(TTargetFPC.Create);
  Targets.Add(TTargetPHP.Create);
  Targets.Add(TTargetC.Create);
  Targets.Add(TTargetJava.Create);
  Targets.Add(TTargetPython.Create);
  Targets.Add(TTargetCSharp.Create);
  Targets.Add(TTargetJavascript.Create);

  LoadFromRegistry(Core.ApplicationInfo.GetRegistryContext);
end;

procedure TCore.DataModuleDestroy(Sender: TObject);
begin
  SaveToRegistry(Core.ApplicationInfo.GetRegistryContext);
  FreeAndNil(Targets);
  FreeAndNil(Project);
  FreeAndNil(StoredDimension);
end;

procedure TCore.LoadFromRegistry(Context: TRegistryContext);
begin
  with TRegistryEx.Create do
  try
    CurrentContext := Context;
    OpenProjectOnStart := ReadBoolWithDefault('OpenProjectOnStart', True);
    if ValueExists('LanguageCode') then
      Translator.Language := Translator.Languages.SearchByCode(ReadStringWithDefault('LanguageCode', ''))
      else Translator.Language := Translator.Languages.SearchByCode('');
    ScaleDPI1.DPI := Point(ReadIntegerWithDefault('DPIX', 96),
      ReadIntegerWithDefault('DPIY', 96));
    ScaleDPI1.AutoDetect := ReadBoolWithDefault('DPIAuto', True);
    OptimizationLevel := TCompilerOptimization(ReadIntegerWithDefault('OptimizationLevel', Integer(coNormal)));
    MemorySize := ReadIntegerWithDefault('MemorySize', 30000);
    CellSize := ReadIntegerWithDefault('CellSize', 256);
    ThemeManager.Theme := ThemeManager.Themes.FindByName(ReadStringWithDefault('Theme', 'System'));
  finally
    Free;
  end;
  LastOpenedList.LoadFromRegistry(TRegistryContext.Create(Context.RootKey, Context.Key + '\' + RecentFilesRegKey));
  Targets.LoadFromRegistry(TRegistryContext.Create(Context.RootKey, Context.Key + '\Compiler'));
  PersistentForm1.RegistryContext := Context;
end;

procedure TCore.SaveToRegistry(Context: TRegistryContext);
begin
  Targets.SaveToRegistry(TRegistryContext.Create(Context.RootKey, Context.Key + '\Compiler'));
  LastOpenedList.SaveToRegistry(TRegistryContext.Create(Context.RootKey, Context.Key + '\' + RecentFilesRegKey));
  with TRegistryEx.Create do
  try
    CurrentContext := Context;
    WriteBool('OpenProjectOnStart', OpenProjectOnStart);
    WriteBool('DPIAuto', ScaleDPI1.AutoDetect);
    WriteInteger('DPIX', ScaleDPI1.DPI.X);
    WriteInteger('DPIY', ScaleDPI1.DPI.Y);
    WriteInteger('OptimizationLevel', Integer(OptimizationLevel));
    WriteInteger('MemorySize', MemorySize);
    WriteInteger('CellSize', CellSize);
    if Assigned(Translator.Language) and (Translator.Language.Code <> '') then
      WriteString('LanguageCode', Translator.Language.Code)
      else DeleteValue('LanguageCode');
    WriteString('Theme', ThemeManager.Theme.Name);
  finally
    Free;
  end;
end;

procedure TCore.SetCurrentTarget(AValue: TTarget);
var
  I: Integer;
begin
  if FCurrentTarget = AValue then Exit;
  FCurrentTarget := AValue;
  for I := 0 to Targets.Count - 1 do
    TTarget(Targets[I]).OnChangeState := nil;
  if Assigned(FCurrentTarget) then begin
    FCurrentTarget.OnChangeState := FormMain.TargetStateChanged;
    FCurrentTarget.OnLog := FormMain.TargetLogExecute;
    FCurrentTarget.OptimizationLevel := OptimizationLevel;
    FCurrentTarget.Messages.OnChange := FormMain.MessagesChanged;
    if FCurrentTarget is TBFTarget then begin
      TBFTarget(FCurrentTarget).MemorySize := MemorySize;
      TBFTarget(FCurrentTarget).CellSize := CellSize;
    end;
  end;
  FormMain.UpdateTargetList;
  FormMain.UpdateInterface;
end;

procedure TCore.ScaleDPI;
var
  I: Integer;
begin
  with ScaleDPI1 do begin
    //DesignDPI := Point(144, 144);
    if (DesignDPI.X <> DPI.X) or (DesignDPI.Y <> DPI.Y) then begin
      //ApplyToAll(DesignDPI);
      for I := 0 to Screen.FormCount - 1 do
      if (Screen.Forms[I].WindowState = wsNormal) or
        (Screen.Forms[I].WindowState = wsMinimized) then begin
        StoreDimensions(Screen.Forms[I], StoredDimension);
        ScaleDimensions(Screen.Forms[I], StoredDimension);
      end;
      // TODO: Transparent image scaling not working properly under linux Gtk2
      // Also screen DPI is not correctly detected under linux Gtk2
      {$IFDEF WINDOWS}
      ScaleImageList(ImageListMain, DesignDPI);
      {$ENDIF}
    end;
  end;
end;

procedure TCore.Init;
begin
  ScaleDPI;
  Translator.Translate;
end;

end.