source: trunk/UPlaylist.pas

unit UPlaylist;

{$mode Delphi}

interface

uses
  Classes, SysUtils, Generics.Collections;

type
  TPlaylistItem = class
    Time: TDateTime;
    Title: string;
    RemoteName: string;
    LocationOriginal: string;
    Location: string;
    Creator: string;
    TrackNum: string;
    Album: string;
  end;

  { TPlaylistItems }

  TPlaylistItems = class(TObjectList<TPlayListItem>)
    function AddNew: TPlaylistItem;
  end;

  { TPlaylist }

  TPlaylist = class
  public
    Items: TPlaylistItems;
    SearchBaseDir: string;
    RemoteBaseDir: string;
    FilteredFileExtensions: array of string;
    procedure Search;
    procedure GenerateM3U;
    procedure GenerateXSPF;
    constructor Create;
    destructor Destroy; override;
  end;


implementation

resourcestring
  SFileNotFound = 'File ''%s'' not found.';

function InStrArray(Value: string; StrArray: array of string): Boolean;
var
  I: Integer;
begin
  I := 0;
  while (I < Length(StrArray)) and (StrArray[I] <> Value) do Inc(I);
  if I < Length(StrArray) then Result := True
    else Result := False;
end;

procedure FileSearch(Files: TStringList; const PathName: string; ExtList: array of string);
var
  Rec: TSearchRec;
  Path: string;
begin
  Path := IncludeTrailingPathDelimiter(PathName);
  if FindFirst(Path + '*', faAnyFile, Rec) = 0 then
  try
    repeat
      if Rec.Name = '..' then continue
      else if Rec.Name = '.' then continue
      else if (Rec.Attr and faDirectory) > 0 then FileSearch(Files, Path + Rec.Name, ExtList)
      else if InStrArray(LowerCase(ExtractFileExt(Rec.Name)), ExtList) then begin
        Files.Add(Path + Rec.Name);
      end;
    until FindNext(Rec) <> 0;
  finally
    FindClose(Rec);
  end;
end;

function FileDate(FileName: string): TDateTime;
var
  fa: LongInt;
begin
  fa := FileAge(FileName);
  if Fa <> -1 then begin
    Result := FileDateToDateTime(fa);
  end else
    raise Exception.Create(Format(SFileNotFound, [FileName]));
end;


{ TPlaylistItems }

function TPlaylistItems.AddNew: TPlaylistItem;
begin
  Result := TPlaylistItem.Create;
  Add(Result);
end;

procedure TPlaylist.Search;
var
  Files: TStringList;
  I: Integer;
  PlaylistItem: TPlaylistItem;
  NameRemoved: Boolean;
  Part: string;
  OutInt: Integer;
begin
  Files := TStringList.Create;
  try
    FileSearch(Files, SearchBaseDir, FilteredFileExtensions);
    for I := 0 to Files.Count - 1 do begin
      PlaylistItem := Items.AddNew;
      with PlayListItem do begin
        RemoteName := RemoteBaseDir + Copy(Files[I], Length(ParamStr(1)) + 2, High(Integer));
        LocationOriginal := StringReplace(RemoteName, '&', '&amp;', [rfReplaceAll]);
        Location := StringReplace(LocationOriginal, '_', ' ', [rfReplaceAll]);
        Album := ExtractFileName(ExtractFileDir(Location));
        NameRemoved := False;

      // Detect Creator from directory name
      if Pos(' - ', Album) > 0 then begin
        Creator := Copy(Album, 1, Pos(' - ', Album) - 1);
        Delete(Album, 1, Length(Creator) + 3);
      end else Creator := Album;
      Title := Copy(ExtractFileName(Location), 1, Length(ExtractFileName(Location)) - Length(ExtractFileExt(Location)));

      // Remove starting with album name from title
      Part := Creator + ' - ';
      if Copy(Title, 1, Length(Part)) = Part then begin
        Delete(Title, 1, Length(Part));
        NameRemoved := True;
      end;

      // Try to load Creator from name
      if (Pos(' - ', Title) > 0) and (not NameRemoved) then begin
        Part := Copy(Title, 1, Pos(' - ', Title) - 1);
        // Avoid track number which can be first title part
        if not TryStrToInt(Part, OutInt) then begin
          Creator := Part;
          Delete(Title, 1, Length(Creator) + 3);
        end;
      end;
        // Detect track number from title
        if Pos(' - ', Title) > 0 then begin
          TrackNum := Copy(Title, 1, Pos(' - ', Title) - 1);
          if TryStrToInt(TrackNum, OutInt) then
            Delete(Title, 1, Length(TrackNum) + 3)
            else TrackNum := '';
        end else TrackNum := '';

        Time := FileDate(Files[I]);
      end;
    end;
  finally
    Files.Free;
  end;
end;

procedure TPlaylist.GenerateM3U;
var
  I: Integer;
begin
  WriteLn('#EXTM3U');
  for I := 0 to Items.Count - 1 do
  with Items[I] do begin
    WriteLn(LocationOriginal);
  end;
end;

procedure TPlaylist.GenerateXSPF;
var
  I: Integer;
begin
  WriteLn('<?xml version="1.0" encoding="UTF-8"?>');
  WriteLn('<playlist version="1" xmlns="http://xspf.org/ns/0/">');
  WriteLn('<trackList>');
  for I := 0 to Items.Count - 1 do
  with Items[I] do begin
    WriteLn('<track>');
    WriteLn('<title>' + Title + '</title>');
    WriteLn('<location>' + LocationOriginal + '</location>');
    WriteLn('<album>' + Album + '</album>');
    WriteLn('<creator>' + Creator + '</creator>');
    WriteLn('<trackNum>' + TrackNum + '</trackNum>');
    WriteLn('<annotation>' + FormatDateTime('yyyy-mm-dd', Time) + '</annotation>');
    WriteLn('</track>');
  end;
  WriteLn('</trackList>');
  WriteLn('</playlist>');
end;

constructor TPlaylist.Create;
begin
  FilteredFileExtensions := ['.mp3', '.ac3', '.flac', '.it', '.m4a', '.wma', '.s3m', '.ogg'];
  Items := TPlaylistItems.Create;
end;

destructor TPlaylist.Destroy;
begin
  FreeAndNil(Items);
  inherited;
end;


end.