source: trunk/USource.pas

unit USource;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, Contnrs, FileUtil, Dialogs, Forms,
  DOM, XMLWrite, XMLRead;

type
  TSourceType = (stFPC, stIDE);

  { TSource }

  TSource = class
  private
    function GetDownloaded: Boolean;
  public
    Id: Integer;
    ProjectName: string;
    ProjectShortName: string;
    ProjectType: string;
    SubversionURL: string;
    VersionNumber: string;
    VersionType: string;
    SourceType: TSourceType;
    ExecutableFile: string;
    property Downloaded: Boolean read GetDownloaded;
    procedure Assign(Source: TSource);
    procedure Download;
    procedure Update;
    procedure ExportTo(Path: string);
    function GetExecutableFile: string;
    function GetPath: string;
    function GetName: string;
  end;

  { TSourceList }

  TSourceList = class(TObjectList)
    function FindById(Id: Integer): TSource;
    procedure UpdateFormFile(FileName: string);
  end;

implementation

uses
  UMainForm, UOperationProgress;

{ TSource }

function TSource.GetDownloaded: Boolean;
begin
  Result := DirectoryExists(GetPath);
end;

procedure TSource.Assign(Source: TSource);
begin
  Id := Source.Id;
  ProjectName := Source.ProjectName;
  ProjectShortName := Source.ProjectShortName;
  ProjectType := Source.ProjectType;
  VersionNumber := Source.VersionNumber;
  VersionType := Source.VersionType;
  SubversionURL := Source.SubversionURL;
  SourceType := Source.SourceType;
  ExecutableFile := Source.ExecutableFile;
end;

procedure TSource.Download;
begin
  OperationProgressForm.CommandLine := 'svn checkout "' + SubversionURL +
    '" "' + GetPath + '"';
  OperationProgressForm.ShowModal;
end;

procedure TSource.Update;
begin
  OperationProgressForm.CommandLine := 'svn update "' + GetPath + '"';
  OperationProgressForm.ShowModal;
end;

procedure TSource.ExportTo(Path: string);
begin
  OperationProgressForm.CommandLine := 'svn export --force "' + GetPath + '" "' +
    Path + '"';
  OperationProgressForm.ShowModal;
end;

function TSource.GetExecutableFile: string;
var
  Postfix: string;
begin
  PostFix := '';
  {$IFDEF WINDOWS}
  PostFix := '.exe';
  {$ENDIF}
  Result := ExecutableFile + Postfix;
end;

function TSource.GetPath: string;
begin
  Result := ExtractFileDir(Application.ExeName) + DirectorySeparator +
    MainForm.SourceDir + DirectorySeparator + IntToStr(Id);
end;

function TSource.GetName: string;
begin
  Result := ProjectShortName + ' ' + VersionNumber +
    ' (' + VersionType + ')';
end;

{ TSourceList }

function TSourceList.FindById(Id: Integer): TSource;
var
  I: Integer;
begin
  I := 0;
  while (I < Count) and (TSource(Items[I]).Id <> Id) do Inc(I);
  if I < Count then Result := TSource(Items[I])
    else Result := nil;
end;

procedure TSourceList.UpdateFormFile(FileName: string);
var
  Doc: TXMLDocument;
  NewNode: TDOMNode;
  NewSubNode: TDOMNode;
  I: Integer;
  NewSource: TSource;
  Child: TDOMNode;
  ExistedSource: TSource;
begin
  if FileExists(FileName) then
  try
    ReadXMLFile(Doc, UTF8Decode(FileName));

    NewNode := Doc.DocumentElement.FindNode('Items');
    Child := NewNode.FirstChild;
    while Assigned(Child) do
    with Child do begin
      try
        NewSource := TSource.Create;
        with NewSource do begin
          NewSubNode := Child.FindNode('ProjectName');
          if Assigned(NewSubNode) then
            ProjectName := UTF8Encode(string(NewSubNode.TextContent));
          NewSubNode := Child.FindNode('ProjectShortName');
          if Assigned(NewSubNode) then
            ProjectShortName := UTF8Encode(string(NewSubNode.TextContent));
          NewSubNode := Child.FindNode('ProjectType');
          if Assigned(NewSubNode) then
            ProjectType := UTF8Encode(string(NewSubNode.TextContent));
          NewSubNode := Child.FindNode('Id');
          if Assigned(NewSubNode) then
            Id := StrToInt(NewSubNode.TextContent);
          NewSubNode := Child.FindNode('SubversionURL');
          if Assigned(NewSubNode) then
            SubversionURL := UTF8Encode(string(NewSubNode.TextContent));
          NewSubNode := Child.FindNode('VersionNumber');
          if Assigned(NewSubNode) then
            VersionNumber := UTF8Encode(string(NewSubNode.TextContent));
          NewSubNode := Child.FindNode('VersionType');
          if Assigned(NewSubNode) then
            VersionType := UTF8Encode(string(NewSubNode.TextContent));
          NewSubNode := Child.FindNode('ExecutableFile');
          if Assigned(NewSubNode) then
            ExecutableFile := UTF8Encode(string(NewSubNode.TextContent));
          NewSubNode := Child.FindNode('SourceType');
          if Assigned(NewSubNode) then
            SourceType := TSourceType(StrToInt(NewSubNode.TextContent));
        end;
        ExistedSource := FindById(NewSource.Id);
        if Assigned(ExistedSource) then begin
          ExistedSource.Assign(NewSource);
        end else begin
          Add(NewSource);
          NewSource := nil;
        end;
      finally
        NewSource.Free;
      end;
      Child := Child.NextSibling;
    end;
  finally
    Doc.Free;
  end;
end;

end.