source: trunk/UWsaFile.pas

unit UWsaFile;

{$mode delphi}

interface

uses
  Classes, SysUtils, Contnrs, Graphics, UDecode, Types;

type
  TWsaFile = class;

  { TWsaFileItem }

  TWsaFileItem = class
    Index: Integer;
    Parent: TWsaFile;
    Offset: Integer;
    Size: Integer;
    procedure GetBitmap(Bitmap: TBitmap);
  end;

  { TWsaFile }

  TWsaFile = class
  private
    F: TFileStream;
    function GetOpenned: Boolean;
  public
    Palette: ^TIntegerDynArray;
    Items: TObjectList; // TList<TWsaFileItem>
    procedure Open(FileName: string);
    procedure Close;
    constructor Create;
    destructor Destroy; override;
    property Openned: Boolean read GetOpenned;
  end;

implementation


{ TWsaFileItem }

procedure TWsaFileItem.GetBitmap(Bitmap: TBitmap);
var
  Flags: Word;
  Slices: Byte;
  Width: Word;
  Height: Byte;
  FileSize: Word;
  DataSize: Word;
  Data: array of Byte;
  Data2: array of Byte;
  Data3: array of Byte;
  X, Y: Integer;
  Offsets: array of Byte;
  C: Integer;
begin
  Parent.F.Position := Offset;
  Flags := Parent.F.ReadWord;
  Slices := Parent.F.ReadByte;
  Width := Parent.F.ReadWord;
  Height := Parent.F.ReadByte;
  FileSize := Parent.F.ReadWord;
  DataSize := Parent.F.ReadWord;
  if (Flags and 1) > 0 then begin
    SetLength(Offsets, 16);
    Parent.F.Read(Offsets[0], Length(Offsets));
  end;
  if (Flags and 2) = 0 then begin
    SetLength(Data, Offset + Size - Parent.F.Position);
    Parent.F.Read(Data[0], Length(Data));
    Data2 := Format80(Data);
  end else begin
    SetLength(Data2, Offset + Size - Parent.F.Position);
    Parent.F.Read(Data2[0], Length(Data));
  end;
  Data3 := Format20(Data2);
  //SetLength(Data3, Length(Data2));
  //Move(Data2[0], Data3[0], Length(Data2));

  // Save to image
  Bitmap.SetSize(Width, Height);
  Bitmap.Canvas.FillRect(0, 0, Bitmap.Width - 1, Bitmap.Height - 1);
  for Y := 0 to Height - 1 do
  for X := 0 to Width - 1 do
    if X + Y * Width < Length(Data3) then  begin
      C := Data3[X + Y * Width];
      if (Flags and 1) > 0 then begin
        if C < 16 then C := Offsets[C]
          else C := Data3[C - 16];
      end;
      C := Parent.Palette^[C];
      Bitmap.Canvas.Pixels[X, Y] := C;
    end;
end;

{ TWsaFile }

function TWsaFile.GetOpenned: Boolean;
begin
  Result := Assigned(F);
end;

procedure TWsaFile.Open(FileName: string);
var
  I: Integer;
  NewItem: TWsaFileItem;
begin
  Close;
  F := TFileStream.Create(FileName, fmOpenRead);
  Items.Count := F.ReadWord;
  for I := 0 to Items.Count - 1 do begin
    NewItem := TWsaFileItem.Create;
    NewItem.Index := I;
    NewItem.Parent := Self;
    NewItem.Offset := F.ReadDWord + 2;
    if I > 0 then
      TWsaFileItem(Items[I - 1]).Size := NewItem.Offset - TWsaFileItem(Items[I - 1]).Offset;
    Items[I] := NewItem;
  end;
  if Items.Count > 0 then
    TWsaFileItem(Items.Last).Size := F.Size - TWsaFileItem(Items.Last).Offset;
end;

procedure TWsaFile.Close;
begin
  if Openned then begin
    Items.Count := 0;
    FreeAndNil(F);
  end;
end;

constructor TWsaFile.Create;
begin
  Items := TObjectList.Create;
end;

destructor TWsaFile.Destroy;
begin
  Close;
  FreeAndNil(Items);
  inherited Destroy;
end;

end.